; bbo.scp
; script pre callback pre Toshiba interny modem
; prikaz &c0 aby nepadal, 
; 

proc main 
;  string cislo ="06262927"     ; telefonne cislo kam bude volat server
  string cislo ="283"     ; telefonne cislo kam bude volat server
  string login = $USERID

  string problem="                                  "
  string command_escape = "+++" 
  string DCD_on = "AT&c0E1^M"
  string DCD_normal = "ATS&c1^M"
  integer i  

  i = 5 
  while i > 0 do 
    waitfor "login:" then l1 until 5
    transmit "^H^M" 
    i = i - 1 
  endwhile 
  problem="nedostal som prvy login:"
  goto err
l1:
  set screen keyboard off
  transmit command_escape
  waitfor "OK" then l2 until 5
  problem="neviem nastavovat modem"
  goto err
l2:
  transmit DCD_on
  waitfor "OK" then l3, "0" then l3 until 2
  problem="neviem nastavit DCD modemu"
  goto err
l3:
  transmit "ato^M"
  waitfor "CONNECT" then l4 until 2 
  problem="neviem sa vratit do datoveho spojenia"
  goto err
l4:
  delay 1
  transmit "^H^H^H^M"
  i = 3 
  while i > 0 do 
    transmit "^H^H^H^M" 
    waitfor "login:" then nalogine until 10 
    i = i - 1 
  endwhile 
  problem="nemam login po nastaveni modemu"
  goto err
nalogine:
  transmit login + "^M"
  waitfor "Password:" until 4
  transmit $PASSWORD, raw
  transmit "^M"
  waitfor login + ": " until 4
  transmit "cbuser^M"
  waitfor login + " ? " until 10
  transmit cislo + "^M"

; pocka kym zlozi a potom kym zavola
  waitfor "NO CARRIER" until 20
;  transmit "at{e1 TERAZ CAKAM NA ZAVOLANIE (180 sekund), nasledovny error si nevsimaj^M"
;  transmit "^M"
  waitfor "2<cr>" then Called, "RING"  then Called until 180 
  problem="nezavolal mi - timeout."
  goto err

Called:
 transmit "ata^M"
 waitfor "login" until 20
 transmit "^M"
 i = 3
  while i > 0 do 
    transmit "^H^H^H^M" 
    waitfor "login:" then cl0 until 5
    i = i - 1 
  endwhile 
  problem="po callb som nedostal login:"
  goto err
cl0:
  set screen keyboard off
  delay 1
  transmit command_escape 
  waitfor "OK" then cl2 until 5
  problem="neviem nastavovat modem cl"
  goto err
cl2:
  transmit DCD_normal
  waitfor "OK" then cl3, "0" then cl3 until 2
  problem="neviem nastavit DCD normal"
  goto err
cl3:
  transmit "ato^M"
  waitfor "CONNECT" until 7 
  delay 1
  transmit "^H^H^H^H^H^M"
 goto end

err:
; povoli vstup z klavesnice, skusi poslat escape (ak som v on-line)
; skusi zapnut CD (aby si videl chybove okno), skusi zlozit (ath)
; zapne echo a napise v com bol problem;
  set screen keyboard on 
  transmit command_escape
waitfor "OK" until 1
  transmit "ATE1^M" 
waitfor "OK" until 1
  transmit "at{e1 MAM PROBLEM, skusim zlozit telefon.^M"
  transmit "at{e1 " + problem + "^M"
  transmit DCD_normal
waitfor "OK" until 1
  transmit "ATH^M"
waitfor "OK" until 1
  halt
end: 
endproc